Scalix Forums

#!/usr/bin/env stap
#
# Copyright (C) 2007 Oracle Corp.
#
# Get the status of read/write every 5 seconds, print top ten entries
#
# This is free software,GNU General Public License (GPL); either version 2, or (at your option) any
# later version.
#
# Usage:
# ./iotop.stp
#

global io_stat
global read_bytes,write_bytes

probe syscall.read.return {
if ($return > 0) {
io_stat[pid(),execname(),uid(),ppid(),"R"] += $return
read_bytes += $return
}
}

probe syscall.write.return {
if ($return >0) {
io_stat[pid(),execname(),uid(),ppid(),"W"] += $return
write_bytes += $return
}
}

probe timer.ms(5000) {
printf("\n%-25s, %-8s%4dKb/sec, %-7s%6dKb, %-7s%6dKb\n\n",ctime(gettimeofday_s()),"Average:",
((read_bytes+write_bytes)/1024)/5,"Read:",read_bytes/1024,"Write:",write_bytes/1024)

/* print header */
printf("%8s %8s %8s %25s %4s %12s\n","UID","PID","PPID","CMD","T","BYTES")

/* print top ten I/O */
foreach ([process,cmd,userid,parent,action] in io_stat- limit 10)
printf("%8d %8d %8d %25s %4s %12d\n",userid,process,parent,cmd,action,io_stat[process,cmd,userid,parent,action])

/* clear data */
delete io_stat
read_bytes = 0
write_bytes = 0
}

probe end{
delete io_stat
delete read_bytes
delete write_bytes
}